De onzekerheidsrelatie van Heisenberg

Namen: ... en ...

Inleiding

In deze serie opgaven zullen we een voorbeeld zien van de werking van de onzekerheidsrelatie van Heisenberg in de quantummechanica. Gebruik dit notebook ook als antwoordblad: je kunt de antwoorden dus gewoon hieronder intypen. Begin met hierboven je namen in te typen, zodat we weten welk notebook van wie is.

Voor we beginnen met de opgave zelf, geven we nog drie belangrijke tips voor het maken van de opdrachten:

Tip: Als je tekst in een nieuwe cel wilt typen, klik dan tussen twee bestaande cellen in (je ziet een lijn verschijnen waar de nieuwe cel komt) en druk op <alt-7> zodat Mathematica weet dat het om tekstinvoer gaat, en niet om Mathematica-code.

Tip: Tijdens het maken van de opgaven zul je zo af en toe code vanuit de tekst willen kopiëren en vervolgens als Mathematica-invoer willen plakken. Je kopieert dan echter automatisch de opmaak van de code mee. Kijk bijvoorbeeld eens naar de volgende code:

Plot[{x^2},{x,-2,2}]

Deze code ziet er op het eerste gezicht normaal uit, maar als je met de muis de tekst selecteert, zul je zien dat de x^2 een lichtere achtergrond krijgt. Hieraan zie je dat die tekst is opgemaakt, en dus waarschijnlijk is gekopieerd uit een ander stuk tekst.

Vaak levert de aanwezigheid van dergelijke opgemaakte tekst in de invoer geen probleem op (probeer dit uit door bovenstaand commando met <shift-enter> uit te voeren), maar soms weigert Mathematica om dergelijke opgemaakte code uit te voeren. Wen je dus aan om in zulke gekopieerde tekst altijd eerst de opmaak te verwijderen! Je doet dat door de invoer met de muis te selecteren, en op <shift-ctrl-spatie> te drukken. (Je kunt ook de menu-optie Format/Clear Formatting kiezen.) Doe dit met de bovenstaande code, en merk op dat de grijze achtergrond achter  x^2 inderdaad verdwijnt.

Tip: Als je Mathematica opnieuw opstart, is het programma alle variabelen en functies vergeten die je eerder gedefinieerd hebt. Dit leidt natuurlijk tot problemen als je functies wilt gebruiken die eerder in de opgave zijn gedefinieerd. Als je dus je computer (of Mathematica) hebt afgesloten, en later weer verder gaat met de opgave, vergeet dan niet om alle functies die eerder in de opgave zijn ingevoerd opnieuw met <shift-enter> te activeren! Ter herinnering: of Mathematica een functie kent of niet, kun je zien aan de kleur van de naam van de functie. Is die naam blauw, dan is de functie nog niet gedefinieerd.

Voor het gemak volgt hieronder een lijstje van de veelgebruikte functies en constanten die we in de loop van deze opgave zullen definiëren. Dit lijstje kun je nu gewoon overslaan; als je later de opgave opnieuw opstart, kun je uit dit lijstje makkelijk de functies activeren die je al eerder ingevoerd hebt. Zo hoef je niet de hele opgave door te zoeken naar de functiedefinities.

Gaussische functie (opgave 1):

Gaussian[A_,c_,b_,x_]:=A Exp[-(1/4)(((((x-c)/b)))^2)]

Kansverdeling (opgave 3):

Kansverdeling[f_]:=Abs[(f^2)]

Genormeerde Gaussische functie (opgave 4):

GaussianNorm[c_,b_,x_]:=(1/(Sqrt[b(Sqrt[2π])])) Exp[-(1/4)(((((x-c)/b)))^2)]

Gaussische kans (opgave 4):

Prob[x0_]:=NIntegrate[Kansverdeling[GaussianNorm[2,3,x]],{x,x0-1/2,x0+1/2}]

Gemiddelde van een golffunctie (opgave 6):

Gemiddelde[f_]:=Integrate[x Kansverdeling[f],{x,-∞,∞}]

Onzekerheid in een golffunctie (opgave 6):

Onzekerheid[f_]:=(Sqrt[Integrate[(((x-Gemiddelde[f]))^2)Kansverdeling[f],{x,-∞,∞}]])

Constante van Planck (opgave 7):

hbar=6.626068 (10^(-34));

Transformatie van positiegolffunctie naar impulsgolffunctie (opgave 7):

ImpulsGF[f_]:=(1/(Sqrt[2Pi hbar]))Integrate[f Exp[(I/hbar) p x],{x,-∞,∞}]

Gemiddelde en onzekerheid voor impuls-golffuncties (opgave 7):

GemiddeldeImp[f_]:=Integrate[p Kansverdeling[f],{p,-∞,∞}]

OnzekerheidImp[f_]:=(Sqrt[Integrate[(((p-GemiddeldeImp[f]))^2)Kansverdeling[f],{p,-∞,∞}]])

Opgave 1: De Gaussische functie

De Gaussische functie is een functie van een variabele x, met de nuttige eigenschap dat die functie snel naar nul gaat als x naar ±∞ gaat. De functie hangt af van 3 parameters: A, c en b.

Gaussian[A_,c_,b_,x_]:=A Exp[-(1/4)(((((x-c)/b)))^2)]

Tip: Als we Mathematica-code in de tekst geven, vergeet dan niet om met <shift-enter> de code te laten uitvoeren. In dit geval zie je dan geen output verschijnen (vaak gebeurt dat wel), maar je ziet wel dat de naam van de functie van kleur verandert. Hiermee geeft Mathematica aan dat het de functie nu kent.

De grafiek van een Gaussische functie (hier met A=1, c=1 en b=1) kunnen we als volgt laten zien:

Plot[Gaussian[1,1,1,x],{x,-4,6}]

Tip: We hebben hier gekozen om de grafiek van x=-4 tot x=6 te plotten. Je kunt natuurlijk spelen met deze waarden om een zo mooi mogelijk plaatje te krijgen.

We willen nu uitzoeken wat de betekenis is van de parameters A,c en b is. We doen dat door de parameters te variëren en de grafieken te vergelijken. Hieronder plotten we de grafiek bijvoorbeeld voor A=1,2 en 3:

Plot[{Gaussian[1,1,1,x],Gaussian[2,1,1,x],Gaussian[3,1,1,x]},{x,-4,6}]

Opgave 1.1: Welke grafiek hoort bij welke waarde van A? Kun je uit deze figuur afleiden welke betekenis de parameter A heeft?

Opgave 1.2: Varieer nu op dezelfde manier de parameter c. Kies de begin- en eindwaarde van x zo dat de plot goed zichtbaar is.

Tip: Je kunt de bovenstaande plot-code kopiëren, hieronder plakken, en dan de parameters aanpassen. Selecteer om te kopiëren de haak naast de cel en druk op <ctrl-c>. Klik vervolgens om te plakken tussen deze cel en de volgende (je ziet een horizontale lijn verschijnen) en druk op <ctrl-v>

Opgave 1.3: Hoe verandert de functie als we c variëren? Wat is dus de betekenis van de parameter c?

Opgave 1.4: Varieer op dezelfde manier de parameter b. Kies de begin- en eindwaarde van x zo dat de plot goed zichtbaar is.

Opgave 1.5: Hoe verandert de functie als we b variëren? Wat is dus de betekenis van de parameter b?

Opgave 2: Kansdichtheid

We komen de Gaussische functie op allerlei plaatsen in de wis- en natuurkunde tegen. Eén tak van de wiskunde waar de Gaussische functie bijvoorbeeld een belangrijke rol speelt, is de kansrekening. In deze deelopgave zien we hiervan een voorbeeld, en komen we ook een ander belangrijk begrip tegen: dat van kansdichtheid. Dit begrip speelt ook in de quantummechanica een grote rol, zoals we verderop nog uitgebreid zullen zien.

Als we een zuivere munt opgooien is de kans 50% dat de munt op "kop" landt, en 50% dat de munt op "munt" landt. Laten we "kop" aangeven met een 1, en "munt" met een 0. We kunnen Mathematica dan een munt laten opgooien door het programma een random geheel getal tussen 0 en 1 te laten kiezen. We doen dit met de functie RandomInteger:

RandomInteger[{0,1}]

Opgave 2.1: Overtuig jezelf ervan dat dit commando doet wat het moet doen door een aantal maal op <shift-enter> te drukken. Geef vervolgens hieronder de code waarmee Mathematica een worp met een zeszijdige dobbelsteen (dus met de getallen 1 t/m 6) kan simuleren.

Als we nu honderd maal een munt willen opgooien, is het natuurlijk niet erg efficiënt om honderd maal op <shift-enter> te drukken. We kunnen Mathematica dat met het commando Table eenvoudig in één keer laten doen:

worpen=100;
worplijst=Table[RandomInteger[{0,1}],{worpen}]

Tip: We hebben hier een puntkomma achter de eerste regel gezet, maar niet achter de tweede. Met behulp van de puntkomma voorkomen we dat Mathematica onnodige "resultaten" (hier: het resultaat "100") weergeeft. (Haal de puntkomma weg en kijk wat het verschil is.)

Het aantal maal dat we "kop" hebben gegooid is het aantal enen uit de bovenstaande lijst. Dit aantal kunnen we eenvoudig tellen door alle getallen uit de lijst op te tellen. (De nullen dragen dan immers niet bij, dus de som is gelijk aan het aantal enen.) Dit doet Mathematica met het commando Total.

worpen=100;
worplijst=Table[RandomInteger[{0,1}],{worpen}];
Total[worplijst]

Merk op dat we weer een extra puntkomma hebben toegevoegd, om niet steeds de hele lijst enen en nullen weer te geven. Als je die lijst wel wilt zien kun je de puntkomma natuurlijk weghalen.

Opgave 2.2: Herhaal de bovenstaande code een aantal maal door opnieuw op <shift-enter> te drukken. Zijn de uitkomsten ongeveer ongeveer zoals je die verwacht had? Waarom, of waarom niet?

Nu willen we een groot aantal series van honderd worpen doen, om te zien hoe de uitkomst van zo'n serie varieert. We gebruiken hiervoor het commando Table twee keer:

worpen=100;
series=200;
totalenlijst=Table[Total[Table[RandomInteger[{0,1}],{worpen}]],{series}]

Tip: Lees ingewikkelde code als hierboven "van binnen naar buiten" om te begrijpen wat er gebeurt. In dit geval:

1) We nemen een random geheel getal tussen 0 en 1 met RandomInteger,
2) We maken een tabel van 100 van deze getallen met Table,
3) We nemen de som van deze tabel met Total,
4) We maken een tabel van 200 van deze totalen met Table.

Met behulp van het commando Count kunnen we tellen hoe vaak bijvoorbeeld het resultaat 49 in deze lijst voorkomt:

worpen=100;
series=200;
totalenlijst=Table[Total[Table[RandomInteger[{0,1}],{worpen}]],{series}];
Count[totalenlijst,49]

Opgave 2.3: Herhaal dit een aantal maal, en probeer ook andere waarden dan 49. Voor welke waarden vind je grote uitkomsten, en voor welke kleine? Kun je dit resultaat begrijpen?

Opgave 2.4: We hebben in de code hierboven berekend hoeveel maal de waarde 49 voorkomt. Waar we echt in geïnteresseerd zijn is niet het aantal maal, maar de frequentie waarmee de waarde 49 voorkomt: het aantal maal gedeeld door het totale aantal series van worpen. Pas de laatste regel in de code zo aan dat Mathematica deze frequentie als resultaat geeft,

In plaats van tellen voor één waarde (hierboven: 49), kunnen we dit natuurlijk ook weer automatisch doen voor een groot aantal waarden. We gebruiken hiervoor weer het commando Table:

worpen=100;
series=200;
totalenlijst=Table[Total[Table[RandomInteger[{0,1}],{worpen}]],{series}];
frequentielijst=Table[{n,Count[totalenlijst,n]/series},{n,30,70}]

Tip: Om geen groot aantal nullen in de lijst te hebben, tellen we hier alleen de uitkomsten n=30 t/m n=70. Om te zien bij welke waarde van n een bepaalde uitkomst hoort, geven we niet alleen de frequentie Count[totalenlijst,n]/series in de tabel weer, maar ook de bijbehorende waarde van n: {n, Count[totalenlijst,n]/series}. Je kunt natuurlijk de grenswaarden n=30 en n=70 weer naar believen wijzigen.

Het aflezen van deze getallen uit een tabel geeft nog niet heel veel inzicht in de resultaten. Duidelijker wordt het als we de resultaten in een grafiek plotten met behulp van ListPlot:

worpen=100;
series=200;
totalenlijst=Table[Total[Table[RandomInteger[{0,1}],{worpen}]],{series}];
frequentielijst=Table[{n,Count[totalenlijst,n]/series},{n,30,70}];
ListPlot[frequentielijst,Joined->True,Filling->Axis]

Tip: Je kunt vaak opties gebruiken om grafieken mooier te maken. We hebben hier de twee opties Joined -> True en Filling -> Axis gebruikt; de eerste verbindt de punten van de ListPlot; de tweede kleurt het oppervlak onder de grafiek tot aan de x-as.

Opgave 2.5: Als je deze code een aantal maal met <shift-enter> opnieuw uitvoert, zul je zien dat de grafiek er steeds iets anders uitziet. Doordat we een relatief klein aantal (200) series van honderd worpen maken, spelen random-effecten nog een grote rol in de frequenties. Deze effecten worden veel kleiner als we een groter aantal series nemen. Pas de bovenstaande code aan zodat een groot aantal series gebruikt wordt.

Tip: Je zult zien dat je binnen redelijke rekentijd tot ongeveer een miljoen series kunt doorrekenen. Mocht je een te grote waarde van series hebben ingevoerd, dan kun je de uitvoering van de code onderbreken door op <alt-punt> te drukken. Dat Mathematica nog aan het rekenen is zie je overigens aan de haak rechts van het commando dat je met <shift-enter> hebt geactiveerd: zolang het programma rekent is die haak vetgedrukt, en worden nieuwe rekenopdrachten niet uitgevoerd.

Het zal je opvallen dat de grafiek die we nu krijgen erg lijkt op de grafiek van een Gaussische functie. Met de nodige wiskunde kan aangetoond worden dat de grafiek inderdaad steeds meer een Gaussische functie benadert als het aantal worpen en vooral het aantal series heel groot worden. De parameters A en b blijken gelijk te zijn aan:

A=(Sqrt[(2/(π worpen))])
b=(Sqrt[(worpen/8)])

Opgave 2.6: Voor het vinden van de bovenstaande formules voor A en b is de nodige geavanceerde wiskunde nodig. Het vinden van een formule voor de parameter c is eenvoudig. Zoals we hierboven gezien hebben is c de plaats van de piek van de Gaussische functie. Waar verwacht je deze piek (dus: welk aantal maal "kop" is het meest waarschijnlijk) bij 100 worpen? Vul dat aantal hieronder op de plek van de XXXXX in en kijk of de frequentieplot en de Gaussische functie inderdaad samenvallen. We hebben hieronder een aantal series van 1000 gekozen; controleer dat de grafiek inderdaad beter wordt als we het aantal series groter maken.

worpen=100;
series=1000;
totalenlijst=Table[Total[Table[RandomInteger[{0,1}],{worpen}]],{series}];
frequentielijst=Table[{n,Count[totalenlijst,n]/series},{n,30,70}];
plot1=Plot[Gaussian[(Sqrt[(2/(Pi worpen))]),XXXXX,(Sqrt[(worpen/8)]),x],{x,30,70}];
plot2=ListPlot[frequentielijst];
Show[plot1,plot2]

Tip: Als je meer grafieken tegelijk wilt tonen, zoals hierboven, doe je dat als volgt:

1) Geef elke grafiek een naam (hier: plot1 en plot2),
2) Zet een puntkomma achter de regels met de individuele grafieken, om ze niet meer te tonen,
3) Gebruik het commando Show om beide grafieken samen te tonen.

Let op: De volgende opgave is wat ingewikkelder dan de andere opgaven. In dit notebook tref je een aantal van deze moeilijkere opgaven aan, aangegeven met een niet-ingekleurde ruit en de toevoeging "voor de liefhebbers". (De gewone opgaven hebben een ingekleurde ruit.) We raden je aan deze opgaven in eerste instantie over te slaan; ze zijn niet essentieel voor de rest van de opdracht. Als je aan het eind van de opdracht tijd over hebt, of thuis met de opdracht verder wilt gaan, kun je dan de opgaven "voor de liefhebbers" die je het leukst lijken alsnog maken.

Opgave 2.7 - voor de liefhebbers: Pas de bovenstaande code zo aan dat de grafiek ook voor andere waarden van het aantal worpen goed getoond wordt. Hiervoor moet je de waarde voor c die je hierboven op de plaats van de XXXXX ingevuld hebt, schrijven als uitdrukking die afhangt van het aantal worpen. Hetzelfde geldt voor de grenswaarden 30 en 70.

We geven hieronder nog een keer de code voor het maken van de frequentielijst voor een aantal worpen van 100 en een aantal series van 100.000. We laten nu alle waarden van n=1 tot n=100 doorrekenen, zodat het eerste element van frequentielijst hoort bij "eenmal kop", het tweede element bij "tweemaal kop", enzovoort. Vergeet niet onderstaande code met <shift-enter> uit te voeren!

worpen=100;
series=100000;
totalenlijst=Table[Total[Table[RandomInteger[{0,1}],{worpen}]],{series}];
frequentielijst=Table[{n,Count[totalenlijst,n]/series},{n,1,100}];

We willen nu de volgende vraag beantwoorden:

Hoe groot is ongeveer de kans dat we bij 100 worpen met een zuivere munt, 40 maal "kop" gooien?

Hiervoor is het belangrijk dat je je beseft dat de frequentie waarmee een gebeurtenis voorkomt, als je een groot aantal metingen doet, de kans op die gebeurtenis goed benadert. Bijvoorbeeld:

- De kans om met een zuivere dobbelsteen 3 te gooien is 1/6
- Als je 6.000.000 maal met een zuivere dobbelsteen gooit, zul je ongeveer 1.000.000 maal 3 gooien.
- De frequentie waarmee je 3 hebt gegooid is dus ongeveer 1.000.000/6.000.000 = 1/6.

De kans op het gooien van 40 maal "kop" kunnen we dus aflezen uit de frequentielijst:

frequentielijst[[40]]

We kunnen ook alleen de frequentie laten vermelden:

frequentielijst[[40,2]]

Tenslotte kunnen we de kans als een numerieke waarde (tussen 0 en 1) laten weergeven:

N[frequentielijst[[40,2]]]

Als je alles goed gedaan hebt, zul je zien dat deze kans ongeveer 1% (0.01) is.

Opgave 2.8: Laat nu op deze manier zien dat de kans om ten minste 40 en ten hoogste 45 maal kop te gooien, ergens tussen de 16% en 17% ligt.

Je hebt hierboven de frequenties in de frequentielijst tussen n=40 en n=45 opgeteld. Er is echter een makkelijke manier om de uitkomst die je hier gevonden hebt te benaderen - een manier die steeds beter wordt als je de aantallen worpen en series groter maakt, zodat de benadering met behulp van de Gaussische functie steeds preciezer wordt. (We zeggen dat de Gaussische functie in deze limiet de precieze kansdichtheid geeft.) De truc bestaat uit de volgende observaties, die je bekend zullen voorkomen als je op school al iets over integreren hebt gehoord:

1) De waarden in de frequentielijst zijn in deze limiet vrijwel gelijk aan die van de Gaussische functie.
2) Elke frequentie kun je "tekenen" als een balkje met breedte 1, en hoogte gelijk aan de frequentie, in de grafiek van de Gaussische functie. (De frequentie van 40 wordt dan zo'n balkje dat loopt van 39.5 naar 40.5)
3) De frequentie is dan dus gelijk aan de oppervlakte van dit balkje.
4) Een som van frequenties (bijvoorbeeld van n=40 t/m n=45 is gelijk aan de oppervlakte van een aantal balkjes naast elkaar.
5) Deze oppervlakte is dus vrijwel gelijk aan de oppervlakte onder de Gaussische functie tussen twee waarden van x (in ons voorbeeld: x=39.5 en x=45.5)
6) Zo'n oppervlakte kun je uitrekenen met een integraal.

Mocht je op school nog niets over integreren hebben gehoord, dan klinkt het bovenstaande je waarschijnlijk nogal cryptisch in de oren. Vraag in dat geval iemand om wat meer uitleg, of onthoud in elk geval het volgende:

De kans op het vinden van een waarde tussen (Subscript[x, 1]) en (Subscript[x, 2]) is gelijk aan de integraal van de kansdichtheid van x=(Subscript[x, 1]) tot x=(Subscript[x, 2]).

We kunnen dit direct testen voor ons voorbeeld, waarin de kansdichtheid zoals we hebben gezien bij goede benadering een Gaussische functie wordt:

Integrate[Gaussian[(Sqrt[(2/(Pi worpen))]),50,(Sqrt[(worpen/8)]),x],{x,39.5,45.5}]

Opgave 2.9: Laat op dezelfde manier zien dat de kans om tenminste 0 maal kop te gooien, en ten hoogste 100 maal, gelijk is aan 100%.

Opgave 3: Van golffunctie naar kansverdeling

De golffunctie is een belangrijk begrip in de quantummechanica. Uit een golffunctie kunnen we de kans bepalen dat een deeltje bijvoorbeeld op een bepaalde plaats is. Een golffunctie lijkt daarmee dus erg op een kansverdeling. Iets preciezer: de kansverdeling die bij een bepaalde golffunctie hoort blijkt de absolute waarde van het kwadraat te zijn:

Kansverdeling[f_]:=Abs[(f^2)]

We zullen in deze opgave werken met een golffunctie die een Gaussische functie is - bijvoorbeeld Gaussian[2, 0, 1, x].

Opgave 3.1: Plot een grafiek van deze golffunctie (bijvoorbeeld van x=-5 tot x=5), en plot met behulp van de zojuist ingevoerde functie Kansverdeling ook een grafiek van de bijbehorende kansverdeling.

Het zal je opvalleen dat ook de kansverdeling de vorm van een Gaussische functie lijkt te hebben, maar met andere parameters. Dat blijkt inderdaad het geval te zijn: de kansverdeling die hoort bij de golffunctie

Gaussian[A, c, b, x]

blijkt de volgende Gaussische functie te zijn:

Gaussian[(A^2),c,(b/(Sqrt[2])),x]

Opgave 3.2: Laat zien dat dit klopt door hieronder de juiste waarden op de plaats van de XXXXX in te vullen, zodat de grafieken over elkaar heen vallen.

Plot[{Kansverdeling[Gaussian[2,0,1,x]],Gaussian[XXXXX,XXXXX,XXXXX,x]},{x,-5,5},PlotStyle->{Thickness[0.03],Thickness[0.01]}]

Tip: Zoals je hierboven ziet kun je met behulp van de optie PlotStyle de dikte van de grafieklijn aanpassen. We hebben dat hier zo gedaan dat beide grafieken tegelijk zichtbaar zijn.

Opgave 3.3 - voor de liefhebbers: Bewijs dat de kansverdeling die bij de gaussische golffunctie Gaussian[A, c, b, x] hoort, inderdaad de gaussische golffunctie Gaussian[(A^2),c,(b/(Sqrt[2])),x] is.

Opgave 4: Normalisatie van de golffunctie

Zoals we in opgave 2.8 hebben gezien, voldoet elke kansverdeling aan een belangrijke eis: de integraal van een kansverdeling over alle mogelijke waarden moet gelijk zijn aan 1 - dat wil zeggen: de kans dat één van alle mogelijke waarden wordt aangenomen, moet gelijk zijn aan 100%. DIt betekent dat niet elke Gaussische functie geschikt is als golffunctie.

Opgave 4.1: Laat met Mathematica zien dat de integraal van x=-∞ tot x=∞ van de kansverdeling die hoort bij de gaussische functie Gaussian[2, 0, 1, x], gelijk is aan 4(Sqrt[2π]). Is Gaussian[2, 0, 1, x] dus een goede golffunctie?

Tip: Het symbool ∞ kun je typen door op <esc> te drukken, dan "inf" te typen, en dan weer op <esc> te drukken. In plaats daarvan kun je overigens ook het Mathematica-commando Infinity gebruiken.

Zoals we hebben gezien, bepaalt de parameter A in de Gaussische functie de hoogte van de grafiek. We willen deze parameter dus zo kiezen dat de Gaussische functie goed genormeerd is - dat wil zeggen: dat de integraal van de bijbehorende kansverdeling gelijk is aan 1.

Een eerste vraag die we daarvoor moeten beantwoorden is: wat is de integraal van de kansverdeling die hoort bij een willekeurige gaussische functie? We vragen dit aan Mathematica:

Integrate[Kansverdeling[Gaussian[A,c,b,x]],{x,-∞,∞}]

Er zullen je twee dingen opvallen: 

1) Deze berekening duurt vrij lang (geef Mathematica er gerust een half minuutje de tijd voor), en
2) Het antwoord is niet erg veelzeggend.

Zoals vaak het geval is, ontstaan deze problemen doordat Mathematica niet weet aan welke voorwaarden de parameters voldoen, en we dus een veel te algemeen probleem willen oplossen. In dit geval moeten we Mathematica vertellen dat de parameters reële getallen zijn (Mathematica kent ook zogenaamde complexe getallen),  en dat de breedte b bovendien een positief getal is.

Opgave 4.2: Herhaal de bovenstaande berekening met de optie Assumptions->{Element[{A,c,b},Reals],b>0}, zodat het antwoord een eenvoudige uitdrukking in A, b en c wordt. Het zal je opvallen dat één van de parameters A, b en c niet in het antwoord voorkomt. Kun je begrijpen waarom dit het geval is?

We voeren nu de genormeerde gaussische functie in:

GaussianNorm[c_,b_,x_]:=(1/(Sqrt[b(Sqrt[2π])])) Exp[-(1/4)(((((x-c)/b)))^2)]

Deze functie hangt alleen nog af van de parameters c en b, maar niet meer van A.

Opgave 4.3: Vergelijk deze definitie met de definitie van de functie Gaussian in opgave 1. Welke waarde hebben we voor A gekozen? Kun je uit het antwoord op opgave 4.2 begrijpen dat dit de juiste waarde is om een goed genormeerde kansverdeling te krijgen?

Opgave 4.4: Plot de kansverdelingen die horen bij de gaussische functies GaussianNorm[0, 1, x], GaussianNorm[0, 2, x] en GaussianNorm[0, 3, x] van x=-10 tot x=10. Kun je aan de grafieken (grofweg) zien dat de normalisatie van de drie functies hetzelfde is?

Opgave 4.5: Kies een aantal waarden voor c en b, en laat met behulp van Integrate zien dat de kansverdelingen van de bijbehorende golffuncties inderdaad goed genormeerd zijn.

Opgave 5: Metingen van de positie

In deze opgave bekijken we een deeltje waarvan de positie als golffunctie een Gaussische functie heeft met c=2 en b=3. De kansverdeling voor de positie van het deeltje is dus Kansverdeling[GaussianNorm[2, 3, x]].

We zijn geïnteresseerd in de kans dat we de positie van het deeltje meten tussen twee bepaalde waarden - bijvoorbeeld tussen x=(5/2) en x=(7/2). Die kans is, zoals we inmiddels weten, gelijk aan de oppervlakte die je in de volgende grafiek ziet:

(* Hele grafiek *)
plot1=Plot[Kansverdeling[GaussianNorm[2,3,x]],{x,-10,14}];
(* Middenstuk grafiek - met arcering *)
plot2=Plot[Kansverdeling[GaussianNorm[2,3,x]],{x,(5/2),(7/2)},Filling->0];
(* Laat de grafieken over elkaar zien *)
Show[plot1,plot2,PlotRange->{{-10,14},{0,0.15}}]

Opgave 5.1: Bereken met behulp van het commando Integrate de bovenstaande oppervlakte. Je zult zien dat het antwoord een nogal onduidelijke uitdrukking is, die gebruik maakt van de functie Erf. (De precieze betekenis van deze functie doet er voor deze opgave niet toe.) Gebruik de functie N om dit antwoord te schrijven als een gewoon getal.

Tip: In plaats van de combinatie N[Integrate[...]] kun je ook de ingebouwde Mathematica-functie NIntegrate[...] gebruiken.

We kunnen het antwoord dat je hebt gevonden, zien als "de kans om het deeltje rond x=3 aan te treffen". De volgende functie generaliseert dit, en berekent op dezelfde manier de kans om het deeltje rond x=x0 aan te treffen:

Prob[x0_]:=NIntegrate[Kansverdeling[GaussianNorm[2,3,x]],{x,x0-1/2,x0+1/2}]

Opgave 5.2: Controleer dat Prob[3] inderdaad het antwoord oplevert dat je in opgave 5.1 hebt gevonden.

Opgave 5.3: Maak nu met het commando Table een tabel die bestaat uit paren {x,Prob[x]}, waar je x laat lopen van -6 tot 10. Geef de uitvoer op een mooie manier weer met het commando Matrixform.

Opgave 5.4: Rond welke waarde van x vind je de grootste waarde voor Prob[x]? Had je dit antwoord kunnen verwachten?

We willen nu de verwachtingswaarde van de positie van het deeltje uitrekenen. (Als je wiskunde A in je vakkenpakket hebt zul je dit begrip waarschijnlijk al eerder hebben gezien.) Een verwachtingswaarde van een meting bereken je als volgt:

1) Vermeningvuldig elke mogelijke uitkomst van de meting met de bijbehorende kans.
2) Tel al deze resultaten op.

De uitkomst die je op deze manier vindt, kun je zien als de gemiddelde uitkomst die je krijgt als je de meting heel vaak herhaalt.

Opgave 5.5: Laat volgens het bovenstaande recept (met pen en papier of met Mathematica) zien dat de verwachtingswaarde van een worp met een zeszijdige dobbelsteen gelijk is aan (7/2). Is dit de uitkomst die je zou hebben verwacht?

Voor het meten van de positie van het deeltje is het lastig om het bovenstaande recept precies uit te voeren, aangezien de positie x een oneindig groot aantal waarden kan aannemen. Gelukkig is het zo dat voor waarden ver van de gemiddelde waarde x=2 de bijbehorende kansen heel klein zijn, zodat we die waarden in een goede benadering kunnen verwaarlozen.

Opgave 5.6: Bereken de verwachtingswaarde van x als volgt: tel met behulp van het commando Sum de waarden van x Prob[x] op voor x=-6 t/m x=10. Is de uitkomst zoals je die verwacht? Kun je de uitkomst nog verbeteren door een groter bereik voor x te kiezen?

Als je hierboven het bereik voor x ruim genoeg hebt gekozen, zul je een antwoord heel dicht bij 2 hebben gevonden. Het lijkt er dus op dat de verwachtingswaarde van de meting precies ligt bij de piek van de Gaussische functie - een erg logisch resultaat. Toch is het antwoord dat Mathematica vindt nog niet helemaal exact, zoals je kunt zien aan het feit dat Mathematica in het antwoord altijd een decimale punt blijft schrijven. Dit komt doordat we nog altijd twee benaderingen maken:

1) We zouden eigenlijk moeten sommeren van x=-∞ tot x=∞,
2) We zouden niet alleen de waarden van de kans rond bijvoorbeeld x=2 en x=3 moeten meenemen in onze berekening, maar ook die voor alle tussenliggende waarden.

Als we deze twee dingen precies doen, verandert de som die we in opgave 5.6 hebben uitgerekend in een integraal. De exacte verwachtingswaarde voor de posite x rekenen we dus als volgt uit:

Integrate[x Kansverdeling[GaussianNorm[2,3,x]],{x,-∞,∞}]

Opgave 5.7: Reken de verwachtingswaarde van de positie x uit voor een aantal verschillende waarden van de parameters c en b, en laat zo zien dat die waarde niet van b afhangt, en gelijk is aan c.

Opgave 6: Spreiding in de positie

We kunnen de redenering uit opgave 5 herhalen voor allerlei andere situaties. De algemene les is: als we een kansverdeling K[x] hebben, en de verwachtingswaarde van een grootheid g[x] willen uitrekenen, doen we dat met behulp van de integraal Integrate[g[x] K[x], {x, -∞, ∞}]. Zo hebben we de verwachtingswaarde van de positie x bijvoorbeeld uitgerekend met de integraal

Integrate[x Kansverdeling[GaussianNorm[2,3,x]],{x,-∞,∞}]

en we hebben gezien dat die verwachtingswaarde gelijk is aan c, de positie van het maximum van de Gaussische functie.

In deze opgave willen we op een soortgelijke manier een grootheid uitrekenen die iets zegt over de spreiding (of: onzekerheid) van de kansverdeleling. Dat wil zeggen: we willen weten hoeveel de positie, als we die meten, gemiddeld zal afwijken van de verwachtingswaarde. Zoals we in opgave 1.5 hebben gezien, kunnen we verwachten dat deze onzekerheid in het geval van een Gaussische golffunctie iets te maken zal hebben met de parameter b.

Opgave 6.1: Teken de grafieken van de kansverdelingen van GaussianNorm[2,1,x], GaussianNorm[2,3,x] en GaussianNorm[2,5,x], waarbij x loopt van -20 tot 24. Voor welke van deze kansverdelingen zal een gemeten positie de grootste kans hebben om ver van x=2 af te liggen?

Tip: Als Mathematica bepaalde grafieken niet helemaal laat zien, gebruik dan de optie PlotRange->All.

Het verschil tussen een gemeten posite x, en de verwachtingswaarde van die meting, 2, is natuurlijk x-2. We zouden dus kunnen proberen de onzekerheid in ons voorbeeld te definiëren als de verwachtingswaarde van x-2:

Integrate[(x-2) Kansverdeling[GaussianNorm[2,3,x]],{x,-∞,∞}]

Als je deze code uitvoert zul je echter zien dat het antwoord bijzonder weinig informatie geeft: het antwoord is precies 0. Dat komt doordat posities links en rechts van x=2 met een tegengesteld teken bijdragen: voor x=3 is bijvoorbeeld x-2=1, en voor x=1 is x-2=-1. Deze twee afwijkingen heffen elkaar in de integraal precies op, en dit levert het uiteindelijke resultaat 0 op.

Om dit "tekenprobleem" op te lossen kunnen we bijvoorbeeld in plaats van de verwachtingswaarde van x-2, de verwachtingswaarde van de absolute waarde Abs[x-2] (of |x-2| in wiskundige notatie) uitrekenen - daarmee worden alle tegengestelde tekens verwijderd. Voor x=3 is bijvoorbeeld |x-2|=1, en voor x=1 is óók |x-2|=1. De tekens zorgen er nu dus niet meer voor dat deze twee bijdragen elkaar in de integraal opheffen.

Opgave 6.3: Reken de verwachtingswaarde van Abs[x-2] uit op dezelfde manier als boven; je zult vinden dat het antwoord nu niet meer gelijk is aan 0. Varieer de parameter b in de Gaussische golffunctie, en laat zien dat deze verwachtingswaarde groter (kleiner) wordt als b groter (kleiner) wordt.

We lijken hiermee dus een goede maat voor de onzekerheid in de positie-meting gevonden te hebben. Natuurkundigen gebruiken echter liever een andere maat. De reden daarvoor is dat de absolute waarde Abs[x-2] een erg "lelijke" functie is. Een veel nettere functie, die ook het bovengenoemde tekenprobleem oplost, is de kwadratische functie (x-2)^2.

Opgave 6.4: Plot de grafieken van de functies Abs[x-2] en (x-2)^2 van x=0 tot x=4. We zagen hierboven dat de functie x-2 leidde tot een "tekenprobleem", wat ervoor zorgde dat de verwachtingswaarde van die functie gelijk werd aan 0. Hoe zie je aan de grafieken dat de functies Abs[x-2] en (x-2)^2 dit probleem niet hebben?

Aan de grafieken die je hierboven geplot hebt zie je ook waarom we Abs[x-2] een "lelijke" functie noemen: de functie heeft een knik (iets netter: "is niet differentieerbaar") bij x=2.

Ook de verwachtingswaarde van (x-2)^2 is echter nog niet precies de maat voor de onzekerheid waarnaar we op zoek zijn. De reden hiervoor is dat we in opgave 1.5 hebben gezien dat b een goede maat is voor de spreiding. In het bijzonder: als b tweemaal zo groot wordt, wordt de breedte van de grafiek ook tweemaal zo groot.

Opgave 6.5: Bereken de verwachtingswaarde van (x-2)^2 op dezelfde manier als je in opgave 6.3 hebt gedaan voor de verwachtingswaarde van  Abs[x-2]. Varieer weer de parameter b. Vul aan: "Als we b tweemaal zo groot (tweemaal zo klein) maken, wordt de verwachtingswaarde van (x-2)^2 ..."

Dit laatste probleem is eenvoudig opgelost: we definiëren de onzekerheid niet als de verwachtingswaarde van (x-2)^2 zelf, maar als de wortel (Mathematica-commando: Sqrt) van die verwachtingswaarde. In ons voorbeeld rekenen we de onzekerheid dus als volgt uit:

Sqrt[Integrate[(((x-2))^2) Kansverdeling[GaussianNorm[2,3,x]],{x,-∞,∞}]]

Opgave 6.6: Varieer de parameter b in de Gaussische golffunctie, en laat zo zien dat de onzekerheid nu wel tweemaal zo groot wordt als b tweemaal zo groot wordt. (Sterker nog: de onzekerheid is precies gelijk aan b!)

Dat de onzekerheid die we nu gedefinieerd hebben precies gelijk is aan b, is geen toeval: we hebben de Gaussische functie precies zo gedefinieerd dat dit het geval is. (De factor (1/4) die je in de definitie terugvindt is bijvoorbeeld om deze reden zo gekozen.) Wat we nu dus gezien hebben, is dat de parameters c en b, die we oorspronkelijk hebben ingevoerd als constantes in een wiskundige definitie, ook een heel belangrijke fysische betekenis hebben: ze geven precies het gemiddelde en de onzekerheid van de kansverdeling die bij de Gaussische functie hoort.

Het zal je misschien zijn opgevallen dat de bovenstaande definitie nog niet helemaal algemeen toepasbaar is: we hebben de verwachtingswaarde van (x-2)^2 berekend omdat onze kansverdeling een gemiddelde van x=2 had. Als we hadden gewerkt met een kansverdeling die een gemiddelde van x=17 had gehad, hadden we de onzekerheid natuurlijk berekend door de verwachtingswaarde van (x-17)^2 uit te rekenen.

Om niet steeds met de hand eerst het gemiddelde van een kansverdeling te hoeven uitrekenen, en dat vervolgens in de onzekerheid te moeten invullen, voeren we de volgende twee functies in die dat automatisch doen:

Gemiddelde[f_]:=Integrate[x Kansverdeling[f],{x,-∞,∞}]

Onzekerheid[f_]:=(Sqrt[Integrate[(((x-Gemiddelde[f]))^2)Kansverdeling[f],{x,-∞,∞}]])

Opgave 6.7: Gebruik deze twee functies om het gemiddelde en de onzekerheid uit te rekenen voor een aantal Gaussische golffuncties, waarbij je nu niet alleen b maar ook c varieert. Laat zo zien dat de antwoorden inderdaad gelijk zijn aan de parameters b en c.

Opgave 6.8 - voor de liefhebbers: De bovenstaande definities werken alleen voor golffuncties waarvan de kansverdeling goed genormeerd is. (Ter herinnering: dat wil zeggen dat de integraal van x=-∞ tot x=∞ gelijk is aan 1.) Schrijf een nieuwe functie Normeer[f_] die een golffunctie vermenigvuldigt met een constante factor, zodat de resulterende golffunctie goed genormeerd is. (Hint: vergeet hierbij niet dat de kansverdeling het kwadraat is van de golffunctie. Als je dus wilt dat de kansverdeling een factor X kleiner wordt, moet je de golffunctie een factor (Sqrt[X]) kleiner maken.) Gebruik de functie Normeer vervolgens om een nieuwe versie van Gemiddelde[f_] en Onzekerheid[f_] te schrijven, zodat ook die functies van toepassing zijn op ongenormeerde golffuncties. Test de functies die je geschreven hebt door ze toe te passen op een aantal ongenormeerde Gaussische golffuncties.

Opgave 7: De onzekerheidsrelatie voor Gaussische golffuncties

De positie-golffunctie bepaalt de kansverdeling voor metingen van de positie x van een deeltje. We kunnen op dezelfde manier voor allerlei andere eigenschappen van het deeltje een golffunctie definiëren. In deze opgave bekijken we zo’n andere golffunctie: de golffunctie die de kansverdeling voor de impuls p van een deeltje bepaalt. (Ter herinnering: de impuls p=m v is de snelheid van een deeltje, vermenigvuldigd met zijn massa.)

Een fundamentele eigenschap van de quantummechanica is nu dat de positie-golffunctie en de impuls-golffunctie niet onafhankelijk van elkaar zijn. Sterker nog: zodra we de positie-golffunctie van een deeltje weten, kunnen we precies de impuls-golffunctie bepalen.

Om die berekening te doen, voeren we eerst de zogenaamde constante van Planck in:

hbar=1.054571726 (10^(-34));

Twee opmerkingen over deze constante:

1) De constante van Planck heeft de eenheid kg (m^2)/s. Mathematica rekent standaard niet met eenheden, dus we geven hier alleen de getalswaarde.

2) Er zijn in de natuurkunde twee “constanten van Planck” in gebruik: de ene is een factor 2π groter dan de andere. De grootste van de twee wordt meestal als h aangegeven, en de kleinste als ℏ (“h-streep”, of in het Engels “h-bar”). Omdat het symbool ℏ nogal lastig te typen is, hebben we deze constante hierboven hbar genoemd.

Met behulp van de constante van Planck kunnen we nu een Mathematica-functie definiëren die een positiegolffunctie omrekent in een impulsgolffunctie:

ImpulsGF[f_]:=(1/(Sqrt[2Pi hbar]))Integrate[f Exp[(I/hbar) p x],{x,-∞,∞}]

Het zou helaas te ver gaan om hier uit te leggen waarom deze functie er zo uitziet, dus we gebruiken de functie hier als “black box”.

Laten we nu als positiegolffunctie weer een Gaussische functie nemen: GaussianNorm[0,1,x]. We kunnen dan de bijbehorende impulsgolffunctie met de bovenstaande functie berekenen:

impgf=ImpulsGF[GaussianNorm[0,1,x]]

Tip: Zoals je ziet hebben we het resultaat een naam gegeven: impgf. In de volgende opgaven kun je veel beter met impgf werken dan met de uitdrukking ImpulsGF[GaussianNorm[0,1,x]]. De reden hiervoor is dat Mathematica de laatste uitdrukking elke keer opnieuw weer wil berekenen, en dat dit erg veel tijd kost.

Hieronder zie je een plot van de impuls-golffunctie:

Plot[impgf,{p,-3hbar,3hbar}]

Opgave 7.1: Plot ook de impuls-kansverdeling Kansverdeling[impgf]; gebruik dezelfde grenswaarden voor p. Wat valt je op aan de eenheden langs de assen? Is de onzekerheid in de impuls van dit deeltje heel groot of juist heel klein?

Opgave 7.2: Laat met behulp van Integrate zien dat de kansverdeling Kansverdeling[impgf] goed genormeerd is. (Zie opgave 4 als je niet meer precies weet hoe dit moet.) Denk er hierbij aan dat je nu p als variabele gebruikt, en niet x!

We willen nu de onzekerheid in de impuls-kansverdeling uitrekenen. Hierbij is er een klein probleem: we hebben de functies Gemiddelde en Onzekerheid gedefinieerd als functies die werken met de variabele x, terwijl de impuls-golffunctie de variabele p heeft. We definiëren nu dus twee nieuwe functies, GemiddeldeImp en OnzekerheidImp, die precies hetzelfde doen als de eerste twee functies - het enige verschil is dat we de variabele x overal door een p vervangen hebben.

GemiddeldeImp[f_]:=Integrate[p Kansverdeling[f],{p,-∞,∞}]

OnzekerheidImp[f_]:=(Sqrt[Integrate[(((p-GemiddeldeImp[f]))^2)Kansverdeling[f],{p,-∞,∞}]])

Opgave 7.3: Bereken met behulp van de functie OnzekerheidImp de onzekerheid voor de golffunctie impgf. Zoals je zult zien is het resultaat een heel klein getal. Valt je iets op als je het resultaat vergelijkt met hbar?

Opgave 7.4: Bereken nu net als hierboven de impuls-golffuncties die horen bij de positie-golffuncties GaussianNorm[0,2,x] en GaussianNorm[0,3,x]. (Geef de resultaten weer een naam, bijvoorbeeld impgf2 en impgf3.) Bereken de onzekerheid in deze golffuncties. Hoe verandert deze onzekerheid als de parameter b verandert?

Opgave 7.5: Laat zien dat in alle drie de voorbeelden geldt dat

	Δx Δp = (ℏ/2).

Hierin is Δx de onzekerheid in de positie-golffunctie (dus, zoals we gezien hebben, onze parameter c), en Δp de onzekerheid in de impuls-golffunctie die we in deze opgave hebben uitgerekend.

De relatie die we hierboven hebben aangetoond is de beroemde onzekerheidsrelatie van Heisenberg.

De fundamentele les uit de onzekerheidsrelatie is: hoe kleiner we de onzekerheid in de plaats maken, hoe groter de onzekerheid in de impuls (en dus: de snelheid) wordt. Het is dus nooit mogelijk om zowel de positie als de impuls van een deeltje exact te bepalen!

Opgave 8: De onzekerheidsrelatie voor algemene golffuncties

In deze opgave willen we bekijken wat de onzekerheidsrelatie inhoudt voor golffuncties die ingewikkelder zijn dan de Gaussische golffunctie. Als voorbeeld nemen we de volgende golffunctie:

Golffunctie[x_]:=Gaussian[1,-3,1,x]+Gaussian[1,3,1,x]

Opgave 8.1: Plot Golffunctie[x] van x=-10 tot x=10. Kun je de vorm van de grafiek begrijpen?

Deze golffunctie is nog niet goed genormeerd:

norm=Integrate[Kansverdeling[Golffunctie[x]],{x,-∞,∞}]

Opgave 8.2: Laat met behulp van de functie N zien dat norm ongeveer gelijk is aan 5. Laat vervolgens zien dat de onderstaande golffunctie wel goed genormeerd is:

GolffunctieNorm[x_]:=(1/(Sqrt[norm]))(Gaussian[1,-3,1,x]+Gaussian[1,3,1,x])

Opgave 8.3: Laat met behulp van de functie Onzekerheid (en de functie N) zien dat de onzekerheid in de golffunctie GolffunctieNorm[x] ongeveer gelijk is aan 3. Geef de onzekerheid die je vindt een naam, bijvoorbeeld dx.

We laten Mathematica nu de bijbehorende impuls-golffunctie berekenen:

igf=ImpulsGF[GolffunctieNorm[x]]

Het resultaat ziet er niet erg mooi uit; we kunnen een beter beeld van het antwoord krijgen door een grafiek van de bijbehorende kansverdeling te tekenen:

Plot[Kansverdeling[igf],{p,-1.5hbar,1.5hbar}]

Opgave 8.4 - voor de liefhebbers: Kun je begrijpen waarom de grafiek drie pieken heeft? (Hint: bekijk de plot die je in opgave 8.1 gemaakt hebt nog eens, en stel je voor wat er gebeurt als we een meting doen die de positie van het deeltje op twee kort opeenvolgende tijdstippen bepaalt. Welke drie uitkomsten van deze meting zijn het meest waarschijnlijk? Wat betekenen deze waarschijnlijke uitkomsten in termen van de snelheid van het deeltje, en dus in termen van de impuls?)

De kansverdeling voor een impulsmeting is weer automatisch goed genormeerd. Doordat de waarden van p zo klein zijn, is het lastig de integraal exact te berekenen. Het is daarom beter om te integreren van bijvoorbeeld -5ℏ tot 5ℏ - buiten dat gebied is de golffunctie toch vrijwel nul.

NIntegrate[Kansverdeling[igf],{p,-5hbar,5hbar}]

Hetzelfde geldt voor het berekenen van de onzekerheid in de impuls p, dus ook daar integreren we nu van -5ℏ tot 5ℏ. We noemen het antwoord dp:

dp=Re[(Sqrt[NIntegrate[(p^2)Kansverdeling[igf],{p,-5hbar,5hbar}]])]

Tip: Het zal je misschien opvallen dat we hier de functie Re hebben gebruikt. De reden is dat Mathematica het antwoord dat we vinden, wil schrijven als een complex getal. (Laat de functie Re weg als je het verschil wilt zien.) Dat is in dit geval niet nodig; met behulp van de functie Re laten we daarom het zogenaamde “imaginaire” deel van het antwoord weg, en bekijken alleen het reële deel.

Opgave 8.5: Vermeningvuldig de hierboven gevonden onzekerheid dp in de impulsmeting, met de onzekerheid dx in de positiemeting die je in opgave 8.3 hebt gevonden. Hoeveel maal groter dan ℏ is het antwoord?

Voor onze nieuwe golffunctie zien we dat het product van de onzekerheden nog steeds erg klein is, maar wel iets groter dan de waarde (ℏ/2) die we voor de Gaussische golffuncties vonden. Heisenberg gaf een wiskundig bewijs voor het feit dat de Gaussische golffunctie de “best mogelijke golffunctie” is - dat wil zeggen: dat voor die golffunctie het product van de onzekerheden het kleinst mogelijk is. De volledige onzekerheidsrelatie kan dus geschreven worden als:

	Δx Δp ≥(ℏ/2)

Opgave 8.6 - voor de liefhebbers: Verzin zelf nog een andere niet-Gaussische golffunctie; zorg dat deze goed genormeerd is, en laat net als hierboven zien dat ook voor deze golffunctie het product van de onzekerheden groter is dan (ℏ/2).